mirror of
https://github.com/gwenhael-le-moine/sway-patched-tray-menu.git
synced 2024-12-26 21:58:08 +01:00
9a1c411abd
References: https://gitlab.freedesktop.org/wlroots/wlroots/-/merge_requests/3871 Adds option to allow tearing per output, as well as an option to force enable or disable tearing for a specific application using a window rule. Only works with fullscreen applications.
44 lines
1.5 KiB
Meson
44 lines
1.5 KiB
Meson
wl_protocol_dir = wayland_protos.get_variable('pkgdatadir')
|
|
|
|
wayland_scanner_dep = dependency('wayland-scanner', native: true)
|
|
wayland_scanner = find_program(
|
|
wayland_scanner_dep.get_variable('wayland_scanner'),
|
|
native: true,
|
|
)
|
|
|
|
protocols = [
|
|
wl_protocol_dir / 'stable/tablet/tablet-v2.xml',
|
|
wl_protocol_dir / 'stable/xdg-shell/xdg-shell.xml',
|
|
wl_protocol_dir / 'unstable/xdg-output/xdg-output-unstable-v1.xml',
|
|
wl_protocol_dir / 'unstable/pointer-constraints/pointer-constraints-unstable-v1.xml',
|
|
wl_protocol_dir / 'unstable/linux-dmabuf/linux-dmabuf-unstable-v1.xml',
|
|
wl_protocol_dir / 'staging/content-type/content-type-v1.xml',
|
|
wl_protocol_dir / 'staging/cursor-shape/cursor-shape-v1.xml',
|
|
wl_protocol_dir / 'staging/tearing-control/tearing-control-v1.xml',
|
|
'wlr-layer-shell-unstable-v1.xml',
|
|
'idle.xml',
|
|
'wlr-output-power-management-unstable-v1.xml',
|
|
]
|
|
|
|
wl_protos_src = []
|
|
|
|
foreach xml : protocols
|
|
wl_protos_src += custom_target(
|
|
xml.underscorify() + '_c',
|
|
input: xml,
|
|
output: '@BASENAME@-protocol.c',
|
|
command: [wayland_scanner, 'private-code', '@INPUT@', '@OUTPUT@'],
|
|
)
|
|
wl_protos_src += custom_target(
|
|
xml.underscorify() + '_server_h',
|
|
input: xml,
|
|
output: '@BASENAME@-protocol.h',
|
|
command: [wayland_scanner, 'server-header', '@INPUT@', '@OUTPUT@'],
|
|
)
|
|
wl_protos_src += custom_target(
|
|
xml.underscorify() + '_client_h',
|
|
input: xml,
|
|
output: '@BASENAME@-client-protocol.h',
|
|
command: [wayland_scanner, 'client-header', '@INPUT@', '@OUTPUT@'],
|
|
)
|
|
endforeach
|