libliftoff/meson.build

project(
	'libliftoff',
	'c',
	version: '0.4.0-dev',
	license: 'MIT',
	meson_version: '>=0.52.0',
	default_options: [
		'c_std=c11',
		'warning_level=3',
		'werror=true',
	],
)

cc = meson.get_compiler('c')

add_project_arguments(cc.get_supported_arguments([
	'-Wundef',
	'-Wmissing-prototypes',
	'-Walloca',
	'-Wdeclaration-after-statement',

	'-Wno-missing-braces',
	'-Wno-unused-parameter',
]), language: 'c')

liftoff_inc = include_directories('include')

drm = dependency('libdrm', include_type: 'system', version: '>= 2.4.108')

liftoff_deps = [drm]

liftoff_lib = library(
	'liftoff',
	files(
		'alloc.c',
		'device.c',
		'layer.c',
		'list.c',
		'log.c',
		'output.c',
		'plane.c',
	),
	include_directories: liftoff_inc,
	version: meson.project_version().split('-')[0],
	dependencies: liftoff_deps,
	install: true,
)

liftoff = declare_dependency(
	link_with: liftoff_lib,
	include_directories: liftoff_inc,
	dependencies: liftoff_deps,
)

if meson.version().version_compare('>= 0.54.0')
	meson.override_dependency('libliftoff', liftoff)
endif

install_headers('include/libliftoff.h')

pkgconfig = import('pkgconfig')
pkgconfig.generate(
	liftoff_lib,
	filebase: meson.project_name(),
	name: meson.project_name(),
	description: 'KMS plane library',
	url: 'https://gitlab.freedesktop.org/emersion/libliftoff',
)

subdir('example')
subdir('test')
Initial experiments 2019-08-21 22:07:37 +02:00			`project(`
Rename pkg-config file to "libliftoff" 2021-02-24 11:01:23 +01:00			`'libliftoff',`
Initial experiments 2019-08-21 22:07:37 +02:00			`'c',`
build: bump version to 0.4.0-dev 2022-08-18 09:18:44 +02:00			`version: '0.4.0-dev',`
Initial experiments 2019-08-21 22:07:37 +02:00			`license: 'MIT',`
build: ignore warnings in libdrm headers In file included from ../log.c:4: In file included from ../include/log.h:4: In file included from ../include/libliftoff.h:8: /usr/local/include/xf86drmMode.h:551:19: error: zero size arrays are an extension [-Werror,-Wzero-length-array] uint32_t lessees[0]; ^ /usr/local/include/xf86drmMode.h:558:19: error: zero size arrays are an extension [-Werror,-Wzero-length-array] uint32_t objects[0]; ^ 2020-10-20 23:19:55 +02:00			`meson_version: '>=0.52.0',`
Initial experiments 2019-08-21 22:07:37 +02:00			`default_options: [`
build: set c_std to c11 This follows https://gitlab.freedesktop.org/mesa/drm/-/merge_requests/249 and fixes a pedantic warning when including libdrm as wrap. Signed-off-by: Stephan Lachnit <stephanlachnit@debian.org> 2022-07-26 10:25:49 +02:00			`'c_std=c11',`
Initial experiments 2019-08-21 22:07:37 +02:00			`'warning_level=3',`
			`'werror=true',`
			`],`
			`)`

			`cc = meson.get_compiler('c')`

			`add_project_arguments(cc.get_supported_arguments([`
build: turn on additional warnings Functions without a prototype can be static, we don't want to deal with alloca, and undefined definitions should be tested with #ifdef. 2021-08-13 15:39:04 +02:00			`'-Wundef',`
			`'-Wmissing-prototypes',`
			`'-Walloca',`
Turn on -Wdeclaration-after-statement Enforces code style. 2023-02-16 20:03:42 +01:00			`'-Wdeclaration-after-statement',`
build: turn on additional warnings Functions without a prototype can be static, we don't want to deal with alloca, and undefined definitions should be tested with #ifdef. 2021-08-13 15:39:04 +02:00
Initial experiments 2019-08-21 22:07:37 +02:00			`'-Wno-missing-braces',`
			`'-Wno-unused-parameter',`
			`]), language: 'c')`

Rename library to liftoff Let's make these planes useful! 2019-09-12 10:39:06 +02:00			`liftoff_inc = include_directories('include')`
Initial experiments 2019-08-21 22:07:37 +02:00
test/libdrm_mock: implement drmCloseBufferHandle() stub 2023-02-15 14:06:01 +01:00			`drm = dependency('libdrm', include_type: 'system', version: '>= 2.4.108')`
Initial experiments 2019-08-21 22:07:37 +02:00
Rename library to liftoff Let's make these planes useful! 2019-09-12 10:39:06 +02:00			`liftoff_deps = [drm]`
Initial experiments 2019-08-21 22:07:37 +02:00
Rename library to liftoff Let's make these planes useful! 2019-09-12 10:39:06 +02:00			`liftoff_lib = library(`
Rename pkg-config file to "libliftoff" 2021-02-24 11:01:23 +01:00			`'liftoff',`
Initial experiments 2019-08-21 22:07:37 +02:00			`files(`
Move plane allocation algorithm to alloc.c And move plane-related functions to plane.c. 2019-10-19 12:43:09 +02:00			`'alloc.c',`
Rename display.c to device.c Forgot to do that when renaming the struct. 2019-11-29 01:51:22 +01:00			`'device.c',`
Initial experiments 2019-08-21 22:07:37 +02:00			`'layer.c',`
			`'list.c',`
Add logging functions This allows turning on and off debug logs, as well as defining a logging callback. 2019-10-07 08:47:53 +02:00			`'log.c',`
Initial experiments 2019-08-21 22:07:37 +02:00			`'output.c',`
Split plane functions into a separate file 2019-10-11 16:09:35 +02:00			`'plane.c',`
Initial experiments 2019-08-21 22:07:37 +02:00			`),`
Rename library to liftoff Let's make these planes useful! 2019-09-12 10:39:06 +02:00			`include_directories: liftoff_inc,`
build: fix library version Fixes the following error: ../meson.build:31:0: ERROR: Invalid Shared library version "0.3.0-dev". Must be of the form X.Y.Z where all three are numbers. Y and Z are optional. 2022-05-24 12:23:01 +02:00			`version: meson.project_version().split('-')[0],`
Rename library to liftoff Let's make these planes useful! 2019-09-12 10:39:06 +02:00			`dependencies: liftoff_deps,`
Initial experiments 2019-08-21 22:07:37 +02:00			`install: true,`
			`)`

Rename library to liftoff Let's make these planes useful! 2019-09-12 10:39:06 +02:00			`liftoff = declare_dependency(`
			`link_with: liftoff_lib,`
			`include_directories: liftoff_inc,`
			`dependencies: liftoff_deps,`
Initial experiments 2019-08-21 22:07:37 +02:00			`)`

build: override Meson dependency Eases use as a subproject. 2023-02-06 11:18:16 +01:00			`if meson.version().version_compare('>= 0.54.0')`
			`meson.override_dependency('libliftoff', liftoff)`
			`endif`

build: install public header file Closes: https://github.com/emersion/libliftoff/issues/41 2020-01-27 11:04:52 +01:00			`install_headers('include/libliftoff.h')`

Initial experiments 2019-08-21 22:07:37 +02:00			`pkgconfig = import('pkgconfig')`
			`pkgconfig.generate(`
build: remove libraries keyword arg from pkgconfig.generate This fixes the following warning: ../subprojects/libliftoff/meson.build:53: DEPRECATION: Library liftoff was passed to the "libraries" keyword argument of a previous call to generate() method instead of first positional argument. Adding liftoff to "Requires" field, but this is a deprecated behaviour that will change in a future version of Meson. Please report the issue if this warning cannot be avoided in your case. 2021-02-24 10:59:23 +01:00			`liftoff_lib,`
Initial experiments 2019-08-21 22:07:37 +02:00			`filebase: meson.project_name(),`
			`name: meson.project_name(),`
build: bump version to 0.1.0 2021-07-01 14:34:53 +02:00			`description: 'KMS plane library',`
build: set pkg-config URL 2023-02-15 11:50:33 +01:00			`url: 'https://gitlab.freedesktop.org/emersion/libliftoff',`
Initial experiments 2019-08-21 22:07:37 +02:00			`)`
Add test framework When testing the library, the libdrm dependency is swapped with a mock libdrm. The test sets up the mock libdrm's internal state and then runs the test. 2019-09-13 09:33:49 +02:00
Move example to its own directory 2019-09-16 22:41:19 +02:00			`subdir('example')`
Add test framework When testing the library, the libdrm dependency is swapped with a mock libdrm. The test sets up the mock libdrm's internal state and then runs the test. 2019-09-13 09:33:49 +02:00			`subdir('test')`