mirror of
https://github.com/awesomeWM/awesome
synced 2024-11-17 07:47:41 +01:00
c7cdb0e479
Previously, these options had two possible values: ON and OFF.
Now, they have three possible values: ON, OFF, and AUTO.
OFF still does what it always did: The feature is just disabled.
With ON and AUTO, we check for the feature. The difference is what
happens when the feature could not be enabled, e.g. because some
dependencies is missing: With AUTO, we just disable the feature (this is
what happened previously with ON). However, with ON, CMake aborts and
prints an error.
Implements: Suggestion by Daniel
https://github.com/awesomeWM/awesome/pull/2665#pullrequestreview-204595138
Signed-off-by: Uli Schlachter <psychon@znc.in>
42 lines
1.3 KiB
CMake
42 lines
1.3 KiB
CMake
# Add a new option with default value "auto":
|
|
# autoOption(FOOBAR "Support foobar")
|
|
#
|
|
# To check if FOOBAR support should be enabled, use:
|
|
# if(FOOBAR)
|
|
#
|
|
# If necessary dependencies for FOOBAR are missing, use:
|
|
# autoDisable(FOOBAR "Did not find baz")
|
|
#
|
|
# Example:
|
|
# autoOption(FOOBAR "Support foobar")
|
|
# if(FOOBAR)
|
|
# Check for FOOBAR here.
|
|
# if(NOT BAZ_FOUND)
|
|
# autoDisable(FOOBAR "Did not find baz")
|
|
# endif()
|
|
# endif()
|
|
|
|
function(autoOption name description)
|
|
set(${name} AUTO CACHE STRING "${description}")
|
|
set_property(CACHE ${name} PROPERTY STRINGS AUTO ON OFF)
|
|
|
|
if((NOT ${name} STREQUAL ON) AND
|
|
(NOT ${name} STREQUAL OFF) AND
|
|
(NOT ${name} STREQUAL AUTO))
|
|
message(FATAL_ERROR "Value of ${name} must be one of ON/OFF/AUTO, but is ${${name}}")
|
|
endif()
|
|
endfunction()
|
|
|
|
function(autoDisable name reason)
|
|
message(STATUS "${reason}")
|
|
if(${name} STREQUAL AUTO)
|
|
message(STATUS "Disabled.")
|
|
SET(${name} OFF PARENT_SCOPE)
|
|
elseif(${name} STREQUAL ON)
|
|
message(SEND_ERROR "Aborting because ${name} was set to ON.")
|
|
else()
|
|
message(AUTHOR_WARNING "Unexpected value for ${name}: ${${name}}.")
|
|
endif()
|
|
endfunction()
|
|
|
|
# vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80:foldmethod=marker
|